วัดปริมาณ carbon dioxide ด้วย SCD-40

ในบทความนี้เป็นการสาธิตการใช้ SCD-40 ในการวัดปริมาณ Carbon dioxide (CO₂) ซึ่ง SCD-40 มีความยืดหยุ่นน่าใช้มาก ๆ เช่น มีทั้งโหมดปกติ และ โหมดประหยัดพลังงานให้เลือกใช้ให้เหมาะสมกับความต้องการ สามารถ calibrate ได้ทั้งแบบ auto และ manual และยังสามารถปรับ offset ให้กับค่าอุณหภูมิที่วัดได้เพื่อให้ SCD-40 คำนวนค่าความชื้นได้ถูกต้องมากยิ่งขึ้น โดยในครั้งนี้เราจะทำแบบง่าย ๆ ก่อน โดยให้วัดค่า carbon dioxide ในโหมดปกติ แล้วแสดงผลที่ computer ผ่าน USB พร้อมทั้งแสดงผลที่หน้าจอ OLED และสามารถร้องเตือน (Alarm) เมื่อค่า carbon dioxide ที่อ่านได้เกินค่าที่กำหนด ในที่นี้จะกำหนดค่าเริ่มต้นที่ 1500 ppm

สิ่งที่ต้องเตรียมมีดังนี้

อุปกรณ์

1. Arduino Nano RP2040 Connect
2. Carbon dioxide Sensor (SCD-40)
3. 128×64 SSD1036 OLED 
4. Buzzer
5. Breadboard and Jumping Wire

Library

1. SCD-40 library (Sensirion)
2. SSD1036 OLED library (U8g2)

ติดตั้ง Hardware

เนื่องจากเราจะสื่อสารระหว่าง Arduino Nano RP2040 Connect กับ SCD-40 และ OLED ผ่าน I2C และ ควบคุม Buzzer ผ่าน Digital I/O โดยเลือกขาที่สะดวก ในที่นี้คือ ขา D7 ดังนั้นเราจะต่อ hardware ดังนี้

ติดตั้ง Library

            ในที่นี้เราจะใช้ library ของ Sensirion สำหรับ SCD-40 และ U8g2 สำหรับ OLED โดยวิธีการติดตั้งสามารถดูได้จากบทความเรื่อง “การติดตั้ง library”

Code

#include

โดยเริ่มต้นเราต้อง include สิ่งที่เราต้องใช้ในที่นี้คือ library ต่าง ๆ เช่น SCD-40 และ OLED

#include <SensirionI2CScd4x.h>
#include <U8g2lib.h>

กำหนดชื่อให้กับ ขาที่ต่อกับ Buzzer และเงื่อนไขในการร้องเตือน (Alarm) ของ Buzzer โดยต้องการให้ Buzzer ร้องเตือนเมื่อค่า carbon dioxide ที่อ่านได้มีค่าตั้งแต่ 1500 ppm ขึ้นไป (CO2_THRESHOLD_BASE) และให้ร้องเตือนเป็นเวลา 5 วินาที (ALARM_INTV) 

#define BUZZER_PIN 7              // D7
#define CO2_THRESHOLD_BASE 1500   // ppm
#define ALARM_INTV 5000           // ms
#define ON 1
#define OFF 0

สร้างตัวแปรที่จำเป็นสำหรับการควบคุมการร้องเตือน โดยมีตัวแปรสำหรับเก็บค่า threshold ที่จะร้องเตือน (alarmThreshold)  ตัวแปรใช้เก็บเวลาที่เริ่มร้องเตือน (alarmStart) และ ตัวแปรสำหรับเก็บสถานะการร้องเตือน (alarmStatus)

unsigned int alarmThreshold = CO2_THRESHOLD_BASE;
bool alarmStatus = OFF;
unsigned long alarmStart = 0;

สร้าง object ที่เป็น sensor และกำหนดตัวแปรสำหรับรับค่าที่อ่านได้จาก SCD40

SensirionI2CScd4x scd40;
uint16_t co2 = 0;
float temperature = 0.0;
float humidity = 0.0;

สร้าง object ที่เป็นหน้าจอ OLED

U8G2_SSD1306_128X64_NONAME_F_HW_I2C oled(U8G2_R0, /* reset=*/U8X8_PIN_NONE);

Setup()

เตรียมความพร้อม(initial)ให้กับ hardware ต่าง ๆ ของเรา

เริ่มจากเชื่อมต่อกับ computer ผ่าน Serial (USB) ด้วยคำสั่ง begin และรอให้การเชื่อมต่อเสร็จเรียบร้อย (ด้วย while loop) ก่อนที่จะทำงานอื่น ๆ ต่อไป เพื่อที่ว่า ถ้าเราจะรีบส่งข้อความอะไรไปยัง computer ข้อความเหล่านั้นจะได้ไม่ตกหล่น ถ้าการเชื่อมต่อยังไม่เสร็จเรียบร้อย ข้อความที่เราส่งก็จะตกหล่นหายไป

แต่ถ้าเราไม่ได้เชื่อมต่อกับ computer ก็ต้อง comment สามบรรทัดนี้ ตามตัวอย่าง ไม่อย่างนั้น พอทำงานมาถึงจุดนี้มันจะรอเชื่อมต่อให้เสร็จทั้ง ๆ ที่เราไม่ได้เชื่อมต่อกับ computer ผลก็คือ โปรแกรมจะไม่ไปไหน จะหยุดแค่ตรงนี้เท่านั้น

  Serial.begin(115200);
  // while (!Serial) {      // Waiting for connection wiht computer completed
  //     delay(100);
  // }

เริ่มต้นการทำงานของ OLED ด้วยคำสั่ง begin แล้วสั่งให้ clear หน้าจอ และปรับความสว่างที่ต้องการ (โดยใช้คำสั่ง setContrast())

  oled.begin();
  oled.clearDisplay();
  oled.setContrast(1);

กำหนดโหมดและค่าเริ่มต้นให้กับ I/O ซึ่งก็คือขาควบคุม Buzzer และ LED_BUILTIN

  pinMode(BUZZER_PIN, OUTPUT);
  digitalWrite(BUZZER_PIN, OFF);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, OFF);

เริ่มต้นการทำงานของ carbon dioxide sensor (SCD-40) โดยส่งคำสั่ง begin แล้วตามด้วยคำสั่ง stopPeriodicMeasurement (stop) ก่อนที่จะสั่ง startPeriodicMeasurement (start) เพื่อเริ่มการวัดค่า carbon dioxide 

สังเกตว่า เราต้องสั่ง stop ก่อนสั่ง start นั่นเพราะว่า เมื่อเราสั่ง start แล้ว sensor จะไม่รับหลาย ๆ คำสั่ง รวมทั้ง start ซ้ำด้วย ดังนั้น ถ้าเราไม่สั่ง stop ก่อนที่จะสั่ง start นั้นจะทำให้เกิดปัญหาเวลาที่เรา upload โปรแกรมเข้าไปใหม่ ในระหว่างการพัฒนา หรือ ตอนที่เรากด “reset” ที่ตัว Arduino เพราะ SCD40 จะมองว่าเป็นการสั่ง start ซ้ำ เนื่องจากเวลาที่เรา upload โปรแกรมใหม่ หรือ การกดปุ่ม reset ที่ตัว Arduino นั้น ตัว sensor ไม่ได้ reset ไปพร้อมกับ Arduino ด้วยนั่นเอง

  scd40.begin(Wire);
  scd40.stopPeriodicMeasurement();
  scd40.startPeriodicMeasurement();

จากคู่มือของ SCD40 เมื่อสั่ง startPeriodicMeasurement แล้ว sensor จะทำการอ่านค่า carbon dioxide ทุก ๆ 5 วินาที ดังนั้น เมื่อสั่ง start แล้วเราก็ต้องรออย่างน้อย 5 วินาที ถึงจะอ่านค่าได้ ดังนั้นแทนที่จะรออยู่เงียบ ๆ เราก็แจ้งให้ผู้ใช้ทราบเสียหน่อยว่า เรากำลังรอการวัดค่าอยู่นะ เพื่อป้องกันการตกใจว่า เอ๊ะ! ทำไมไม่ทำงาน โดยการ ส่งข้อความไปแสดงที่ computer และแสดงข้อความที่หน้าจอ OLED ด้วย

  Serial.println("Waiting for measurement...");

ส่วนการแสดงข้อความที่หน้าจอ OLED จะยุ่งยากกว่านิดหน่อย และการที่เราจะสั่งว่าให้แสดงอะไรออกที่หน้าจอนั้น มันจะไม่ได้ออกไปที่หน้าจอทันที มันจะเป็นการเก็บข้อมูลที่เราจะให้แสดงออกหน้าจอนั้นไว้ที่ memory ที่เรียกว่า buffer ก่อน แล้วค่อยส่งข้อมูลจาก buffer ออกหน้าจอทีเดียว ดังนั้น ขั้นตอนในการแสดงข้อมูลที่หน้าจอก็จะเริ่มด้วย การ clear buffer (clearBuffer) แล้วก็ส่งข้อมูลที่จะแสดงที่หน้าจอไปเก็บยัง buffer โดยที่เราต้องกำหนด Font เอง ซึ่งเราต้องเลือกทั้งลักษณะ และขนาด (เลือกได้จาก https://github.com/olikraus/u8g2/wiki/fntlistall) และ กำหนดตำแหน่งที่จะแสดงตัวหนังสือบนหน้าจอเองด้วย รวมทั้ง ถ้าข้อความยาวเกินกว่าหน้าจอ เราก็ต้องแบ่งบรรทัดเองอีกด้วย (แต่ถึงแม้ว่าจะรู้สึกว่ามันยุ่งยากจัง แต่พอเริ่มชินแล้วเราจะชอบ เพราะมันให้อิสระเราในการทำอะไรกับหน้าจอก็ได้เลย) หลังจากสั่งว่าจะให้แสดงอะไรออกที่หน้าจอแล้ว เราก็ทำการส่งข้อความทั้งหมดที่อยู่ใน buffer (sendBuffer) ออกไปที่หน้าจอพร้อมกันก็จะได้โค้ดดังนี้

  oled.clearBuffer();
  oled.setFont(u8g2_font_siji_t_6x10);
  oled.drawStr(0, 30, "Waiting for");
  oled.drawStr(0, 40, "measurement....");
  oled.sendBuffer();

Loop()

ในส่วนของ loop เราจะให้มีการทำงานดังนี้

Data Ready?

เนื่องจากการทำงานของตัว SCD40 ในโหมดนี้จะวัดค่า CO₂ และเตรียมข้อมูลให้เราอ่านทุก ๆ 5 วินาที ดังนั้นเราต้องตรวจว่ามีข้อมูลให้เราหรือยัง โดยการเรียกใช้คำสั่ง getDataReadyFlag ดังนี้

  bool dataReady = false;
  scd40.getDataReadyFlag(dataReady);
  if (dataReady) {

อ่านค่า CO2, Temperature, Humidity

ถ้ามีข้อมูลแล้ว ค่อยเรียกใช้คำสั่ง readMeasurement เพื่ออ่านข้อมูลจาก SCD40 ง่าย ๆ ทีเดียวได้ทั้งสามค่าเลย  ดังนี้

    scd40.readMeasurement(co2, temperature, humidity);

แสดงค่าที่ computer

จากนั้นก็นำค่าที่ได้เหล่านี้ส่งไปที่ computer ผ่านสาย USB ด้วยคำสั่ง Serial.print() ดังนี้

    Serial.print("CO2:");
    Serial.print(co2);
    Serial.print("  ");
    Serial.print("Temperature:");
    Serial.print(temperature);
    Serial.print("  ");
    Serial.print("Humidity:");
    Serial.println(humidity);

คำสั่ง print() ทั้งหมดนี้จะแสดงค่าต่าง ๆ ออกมาอยู่บรรทัดเดียวกัน และมีคำสั่ง println() ในบรรทัดสุดท้าย เพื่อบอกว่า เมื่อแสดงค่าแล้วให้ขึ้นบรรทัดใหม่ เพื่อเตรียมแสดงข้อมูลชุดต่อไป ซึ่งถ้าเราใช้ Tools -> Serial Monitor ก็จะเห็นข้อมูลส่งมาดังนี้

และเมื่อเราใช้ Tools -> Serial Plotter ก็จะได้กราฟแสดงข้อมูลทั้งสามออกมาสวย ๆ ดังนี้

เราสามารถแสดงข้อมูลบางตัวได้ โดยการติ๊กที่เครื่องหมายถูกด้านหน้าชื่อค่าต่าง ๆ ได้ด้วย ทำให้กราฟเราแสดงช่วงของค่าที่วัดได้ให้เหมาะสมมากยิ่งขึ้น ลองกดเล่นกันดูนะครับ

แสดงค่าที่ OLED

ต่อมาเราก็แสดงค่าที่อ่านได้บนหน้าจด OLED ด้วย โดยเราเริ่มจาก clearBuffer เพื่อที่จะล้าง memory ที่เก็บข้อมูลสำหรับแสดงที่หน้าจอ OLED แล้วเราก็ใส่คำสั่งต่าง ๆ เพื่อที่จะส่งค่าที่จะแสดงที่หน้าจอลง buffer แล้วปิดท้ายด้วยคำสั่ง sendBuffer() เพื่อส่งข้อมูลใน buffer ทั้งหมดไปแสดงที่หน้าจอ OLED ดังนี้

    oled.clearBuffer();

    oled.setFont(u8g2_font_8x13_tf);
    oled.drawStr(0, 10, "CO");
    oled.setFont(u8g2_font_siji_t_6x10);
    oled.drawStr(16, 14, "2");
    oled.setFont(u8g2_font_siji_t_6x10);
    oled.drawStr(0, 22, "(ppm)");

    String co2_string = String(co2);
    oled.setFont(u8g2_font_courB24_tf);
    int x_pos = (oled.getDisplayWidth() - oled.getStrWidth(co2_string.c_str()));
    oled.setCursor(x_pos, 22);
    oled.print(co2_string);

    oled.setFontMode(1);
    oled.setDrawColor(2);
    oled.drawBox(0, 31, 60, 11);
    oled.drawBox(70, 31, 60, 11);
    oled.setFont(u8g2_font_6x12_t_symbols);
    oled.drawGlyph(20, 41, 176);
    oled.drawGlyph(26, 40, 67);
    oled.drawStr(90, 40, "%");
    oled.drawStr(100, 40, "RH");

    oled.setFont(u8g2_font_courB18_tf);
    oled.setCursor(0, 62);
    oled.print(temperature, 1);
    oled.setCursor(70, 62);
    oled.print(humidity, 1);

    oled.sendBuffer();

ซึ่งจากโค้ดด้านบน ก็จะได้หน้าจอออกมาแบบนี้ ส่วนใครชอบแบบไหนก็ลองปรับแต่งกันดู

ควบคุม Alarm (alarmControl)

ในส่วนของ การควบคุม Alarm (buzzer ส่งเสียง และ LED สว่าง) จะแยกเป็นอีก function เพื่อไม่ให้ดูยุ่งเกินไป ในส่วนของ Alarm นี้อาจทำง่าย ๆ แค่ ถ้าค่า CO₂ ที่อ่านได้เกินค่าที่กำหนด ก็ให้ Alarm ถ้าเมื่อใดค่าที่อ่านได้ต่ำกว่าค่าที่กำหนดก็หยุด Alarm 

แต่จากประสบการณ์ มันจะค่อนข้างน่ารำคาญถ้าจะให้ Alarm โดยให้ buzzer ดังตลอดจนกว่าค่า CO₂ จะต่ำกว่าที่กำหนด ดังนั้นจึงให้ Alarm แค่เวลาที่กำหนด (ในที่นี้คือ 5 วินาที ซึ่งสามารถเปลี่ยนแปลงได้โดยเปลี่ยนค่า ALARM_INTV) แล้วให้ดังอีกครั้งเมื่อค่า CO2 ที่วัดได้เกินค่าปัจจุบันไปอีก 500 ppm ซึ่งก็จะ Alarm อย่างนี้ไปเรื่อย ๆ จนกว่าค่า CO₂ จะต่ำกว่าค่าเริ่มต้น (CO2_TRESHOLD_BASE) จึงปรับค่า threshold กลับมาเป็น ค่าเริ่มต้นอีกครั้ง โดยมี logic การทำงานดังนี้

ก็จะได้ code ออกมาดังนี้

void alarmControl() {
  if (co2 >= alarmThreshold) {
    if ((alarmStatus == OFF)) {
      digitalWrite(BUZZER_PIN, HIGH);   // Alarm
      digitalWrite(LED_BUILTIN, HIGH);  // Alarm
      alarmStatus = ON;                 // Alarm
      alarmStart = millis();

    } else if ((millis() - alarmStart) > ALARM_INTV) {
      digitalWrite(BUZZER_PIN, LOW);    // Alarm
      digitalWrite(LED_BUILTIN, LOW);   // Alarm
      alarmStatus = OFF;                // Alarm
      alarmStart = 0;
      alarmThreshold = co2 + 500;
    }
  } else {
    digitalWrite(BUZZER_PIN, LOW);      // Alarm
    digitalWrite(LED_BUILTIN, LOW);     // Alarm
    alarmStatus = OFF;                  // Alarm
    alarmStart = 0;

    if (co2 < CO2_THRESHOLD_BASE) {
      alarmThreshold = CO2_THRESHOLD_BASE;
    }
  }
}

ข้อสังเกต

จาก code ด้านบนจะเห็นว่า ในส่วนที่เป็น Alarm นั้นมีหลายบรรทัด และถูกเขียนซ้ำกันบ่อย และต่อไปถ้าจะแก้ไขในส่วนของ Alarm ไม่ว่าจะเพิ่มหรือลดการทำงานของ Alarm ก็จะต้องแก้ทั้งสามที่เหมือน ๆ กัน ทำให้มีโอกาสแก้ไม่ครบ ดังนั้นจึงแยก code ส่วนนี้ออกมาเป็นอีก function ดังนี้

void setAlarm(bool state) {
  digitalWrite(BUZZER_PIN, state);
  digitalWrite(LED_BUILTIN, state);
  alarmStatus = state;
}

และ code ในส่วน alarmControl() ก็จะเป็นอย่างนี้

void alarmControl(void) {
  if (co2 >= alarmThreshold) {
    if ((alarmStatus == OFF)) {
      setAlarm(ON);
      alarmStart = millis();

    } else if ((millis() - alarmStart) > ALARM_INTV) {
      setAlarm(OFF);
      alarmStart = 0;
      alarmThreshold = co2 + 500;
    }
  } else {
    setAlarm(OFF);
    alarmStart = 0;

    if (co2 < CO2_THRESHOLD_BASE) {
      alarmThreshold = CO2_THRESHOLD_BASE;
    }
  }
}

เพียงเท่านี้ เราก็จะได้เครื่องวัด carbon dioxide ไว้เล่นสนุกแล้ว

เพื่อความสะดวกในการใช้งาน และความสวยงาม ก็สามารถนำไปใส่กล่อง หรือขวดให้เหมาะสมได้

เพื่อความสะดวก ด้านล่างนี้คือ code ทั้งหมดครับ

#include <SensirionI2CScd4x.h>
#include <U8g2lib.h>

#define BUZZER_PIN 7              // D7
#define CO2_THRESHOLD_BASE 1500   // ppm
#define ALARM_INTV 5000           // ms
#define ON 1
#define OFF 0

unsigned int alarmThreshold = CO2_THRESHOLD_BASE;
bool alarmStatus = OFF;
unsigned long alarmStart = 0;

SensirionI2CScd4x scd40;
uint16_t co2 = 0;
float temperature = 0.0;
float humidity = 0.0;

U8G2_SSD1306_128X64_NONAME_F_HW_I2C oled(U8G2_R0, /* reset=*/U8X8_PIN_NONE);

void setup() {
  
  Serial.begin(115200);
  while (!Serial) {      // Waiting for connection wiht computer completed
      delay(100);
  }

  oled.begin();
  oled.clearDisplay();
  oled.setContrast(1);

  pinMode(BUZZER_PIN, OUTPUT);
  digitalWrite(BUZZER_PIN, OFF);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, OFF);

  scd40.begin(Wire);
  scd40.stopPeriodicMeasurement();
  scd40.startPeriodicMeasurement();

  Serial.println("Waiting for measurement...");

  // oled.clearBuffer();
  oled.setFont(u8g2_font_siji_t_6x10);
  oled.drawStr(0, 30, "Waiting for");
  oled.drawStr(0, 40, "measurement....");
  oled.sendBuffer();
}

void loop() {

  bool dataReady = false;
  scd40.getDataReadyFlag(dataReady);
  if (dataReady) {

    scd40.readMeasurement(co2, temperature, humidity);

    Serial.print("CO2:");
    Serial.print(co2);
    Serial.print("  ");
    Serial.print("Temperature:");
    Serial.print(temperature);
    Serial.print("  ");
    Serial.print("Humidity:");
    Serial.println(humidity);

    oled.clearBuffer();

    oled.setFont(u8g2_font_8x13_tf);
    oled.drawStr(0, 10, "CO");
    oled.setFont(u8g2_font_siji_t_6x10);
    oled.drawStr(16, 14, "2");
    oled.setFont(u8g2_font_siji_t_6x10);
    oled.drawStr(0, 22, "(ppm)");

    String co2_string = String(co2);
    oled.setFont(u8g2_font_courB24_tf);
    int x_pos = (oled.getDisplayWidth() - oled.getStrWidth(co2_string.c_str()));
    oled.setCursor(x_pos, 22);
    oled.print(co2_string);

    oled.setFontMode(1);
    oled.setDrawColor(2);
    oled.drawBox(0, 31, 60, 11);
    oled.drawBox(70, 31, 60, 11);
    oled.setFont(u8g2_font_6x12_t_symbols);
    oled.drawGlyph(20, 41, 176);
    oled.drawGlyph(26, 40, 67);
    oled.drawStr(90, 40, "%");
    oled.drawStr(100, 40, "RH");

    oled.setFont(u8g2_font_courB18_tf);
    oled.setCursor(0, 62);
    oled.print(temperature, 1);
    oled.setCursor(70, 62);
    oled.print(humidity, 1);

    oled.sendBuffer();
  }  // if (dataReady)

  // Alarm Control
  alarmControl();

}  // Loop

void alarmControl(void) {
  if (co2 >= alarmThreshold) {
    if ((alarmStatus == OFF)) {
      setAlarm(ON);
      alarmStart = millis();

    } else if ((millis() - alarmStart) > ALARM_INTV) {
      setAlarm(OFF);
      alarmStart = 0;
      alarmThreshold = co2 + 500;
    }
  } else {
    setAlarm(OFF);
    alarmStart = 0;

    if (co2 < CO2_THRESHOLD_BASE) {
      alarmThreshold = CO2_THRESHOLD_BASE;
    }
  }
}

void setAlarm(bool state) {
  digitalWrite(BUZZER_PIN, state);
  digitalWrite(LED_BUILTIN, state);
  alarmStatus = state;
}

คำเตือน

ขอย้ำอีกครั้งว่า ค่าที่อ่านได้อาจคลาดเคลื่อนด้วยหลายปัจจัย อย่านำไปใช้ในสถานการณ์ที่ความคลาดเคลื่อนนี้อาจก่อให้เกิดความเสียหายต่อชีวิตและทรัพย์สินรวมถึงสิ่งแวดล้อมนะครับ

ในตอนต่อ ๆ ไป เราจะมาปรับปรุงระบบนี้ให้น่าสนใจมากยิ่งขึ้นไปอีก เพราะยังมีอะไรให้ทำกับระบบนี้อีกมาก เช่น สามารถ calibrate ค่า CO2 ได้ สามารถกำหนด offset ให้กับค่าอุณหภูมิที่อ่านได้ ทำให้ได้ค่าอุณหภูมิ และความชื้นที่ถูกต้องมากยิ่งขึ้น รวมทั้ง เราจะใช้ความสามารถความเป็น dual core ของ RP2040 มาใช้ประโยชน์ และการอ่านค่าจากระยะไกล โดยใช้ Bluetooth หรือแม้แต่ส่งขึ้น cloud เพื่อ monitor ได้จากมืออีกด้วย น่าสนใจมาก ๆ ใช่ไหมล่ะครับ คอยติดตามกันนะครับ

เอกสารอ้างอิง

1. SCD-40 data sheet (https://sensirion.com/media/documents/E0F04247/631EF271/CD_DS_SCD40_SCD41_Datasheet_D1.pdf)